Галактика в вопросах и ответах

Код: Выделить всё

const
  cmPrintDoc = 3440;
End;

Interface SelectDogovor;
Show at(1,1,92,30);
  var
    _nRecDogovor:comp;

  create view
  as  select *
      from dogovor
      bounds cVidDog = 281474976710671==dogovor.CVIDDOG(noindex)
      
      bounds cDogovor = _nRecDogovor == dogovor.nrec
      
      bounds cCalplan = dogovor.nrec == calplan.cdogovor and 0==calplan.directplat and 1==calplan.DIRECTMC(noindex);
/**********************************************************************/
   screen DocScreen;
     show at (,,,2);
     buttons cmPrintDoc;
     <<
       <.Печать диараммы.>
     >>
   end
/**********************************************************************/	
  Browse B1;
  show at (,3,,);
    fields
      dogovor.nodoc 'Номер':[7],Protect;
      dogovor.ddoc  'Дата':[80],Protect;
  end;
/**********************************************************************/	
var 
 IsFirstRec : boolean;
 counter : integer;
datastream DocDataStream
 (
     [DogovorNoDoc] Dogovor.noDoc;   //элемент "нулевого" уровня
     [DogovorDDoc] Dogovor.DDoc;   //элемент "нулевого" уровня
    
    table Calplan       //элемент уровня table
    (
      [PosY]      counter;
      [NoDoc]     Calplan.nodoc;
      [DateStart] CALPLAN.DFROM;
      [DateEnd]   Calplan.dto;
    );
    
 )
/**********************************************************************/	
  handleevent table Calplan //обработчик dataset
    cmPreProcess:
    {
      PushBounds(tbcDogovor);
      PushBounds(tbcCalplan);
	  counter := 0;
	}
    
    cmOnProcess:
    {
        counter := counter + 1;
        if( not NextVisual )
          BreakProcess;
    }
      end;

/**********************************************************************/	
  handleevent // обработчик datastream
    cmPreProcess:
      StartNewVisual(vtRotateVisual, 
        vfTimer + vfBreak + vfConfirm, 
        'Формируется отчет', 0);

    cmPostProcess:
      StopVisual('', 0);
  end;
end;

/**********************************************************************/	
  HandleEvent// обработка событий формы
/**********************************************************************/	
  cmInit:
   {
     PushBounds(tbcVidDog);
   }
/**********************************************************************/	
  cmPrintDoc :
   {
    _nRecDogovor := dogovor.nrec;
    RunFReport(DocDataStream, '', false);
    PopBounds(tbcDogovor);
    PopBounds(tbcCalplan);
   };
/**********************************************************************/	
  cmDone:
   {
     CloseInterface(cmDefault);
     stop;
   }
end;
end.