Галактика в вопросах и ответах

Код: Выделить всё

create view cvData
as select
  ( GetBuxSum1 ) ( FieldName = BuxSumOplPred ),
  ( GetBuxSum2 ) ( FieldName = BuxSumOplPost ),
  ( BuxSumOplPred+BuxSumOplPost ) ( FieldName = BuxSumOpl ),
  ( GetBuxSum3 ) ( FieldName = BuxSumOtgr ),
  ( BuxSumOpl-BuxSumOtgr ) ( FieldName = BuxSumSaldo ),
  ( GetOperSum2 ) ( FieldName = OperSumOpl ),
  ( GetOperSum1 ) ( FieldName = OperSumOtgr ),
  ( OperSumOpl-OperSumOtgr ) ( FieldName = OperSumSaldo ),
  ( BuxSumSaldo-OperSumSaldo ) ( FieldName = SumSaldo ),

  *
from
  OBOROT, KATSOPR, SPSOPR, KATORG, DOGOVOR, BASEDOC, BaseFin, StepDoc,
  synonym OBOROT OBOROT1,
  synonym OBOROT OBOROT2,
  synonym OBOROT OBOROT3
where ((
                 0 == BASEDOC.CVAL        (noIndex)
  and          201 == BASEDOC.VIDDOC      (noIndex)
  and     BASEDOC.CORG /== KATORG.NREC
  and BASEDOC.CDOGOVOR /== DOGOVOR.NREC
// БУХ АВАНС (Д62.01К62.02)
  and         '562'== OBOROT1.SCHETO      (noIndex)
  and         '01' == OBOROT1.SUBOSSCH    (noIndex)
  and         '562'== OBOROT1.SCHETK      (noIndex)
  and         '02' == OBOROT1.SUBSCHK     (noIndex)
  and BASEDOC.NREC == OBOROT1.KAUKS[4]    (noIndex)
// БУХ ПостОплата (К62.02)
  and         '562'== OBOROT2.SCHETK      (noIndex)
  and         '02' == OBOROT2.SUBSCHK     (noIndex)
  and BASEDOC.NREC == OBOROT2.KAUKS[4]    (noIndex)
  and  ( OBOROT2.SCHETO<>'562' )
// БУХ Отгрузка (Д62.02)
  and         '562'== OBOROT3.SCHETO      (noIndex)
  and         '02' == OBOROT3.SUBOSSCH    (noIndex)
  and BASEDOC.NREC == OBOROT3.KAUOS[4]    (noIndex)
  and  ( OBOROT3.SCHETK<>'562' )
// Опер Отгрузка
  and BASEDOC.NREC == STEPDOC.CBASEDOC
  and StepDoc.NREC == KATSOPR.CSTEPDOC
  and KATSOPR.NREC == SPSOPR.CSOPR
// Опер оплаты
  and BASEDOC.NREC == BASEFIN.CBASEDOC
));

function GetBuxSum1:double;
begin
  result := 0;
  cvData._loop OBOROT1 result := result + cvData.OBOROT1.SUMOB;
end;

function GetBuxSum2:double;
begin
  result := 0;
  cvData._loop OBOROT2 result := result + cvData.OBOROT2.SUMOB;
end;

function GetBuxSum3:double;
begin
  result := 0;
  cvData._loop OBOROT3 result := result + cvData.OBOROT3.SUMOB;
end;

function GetOperSum1:double;
begin
  result := 0;
  cvData._loop SPSOPR result := result + if(cvData.KATSOPR.VHODNAL=2,cvData.SPSOPR.KOLFACT*cvData.SPSOPR.PRICE+cvData.SPSOPR.SUMNDS,cvData.SPSOPR.KOLFACT*cvData.SPSOPR.PRICE);
end;

function GetOperSum2:double;
begin
  result := 0;
  cvData._loop BASEFIN result := result + if(cvData.BASEFIN.direct=1,cvData.BASEFIN.summa,-cvData.BASEFIN.summa);
end;