Галактика в вопросах и ответах

Код: Выделить всё

interface McGroupMc 'Мат.ценности по группам';
    Show at (8,4,88,24);
Table STRUCT TreeMC ""
(
  nRec     : comp ,
  Name     : String[40] ,
  NameGr   : String[40] ,
  cRec     :comp,
  Node     :Word // Признак группы
)
With Index
(
  main01  = nRec,
  main02  = cRec+Node,
  main03  = Node
)
;

Var 
  CurOwner:Comp;
  CurNode :Word;

Create view TreeView as 
Select
    TreeMC.*
  from
    TreeMC,
    TreeMC TreeMC1 
  Where
  ((
    TreeMc.Nrec == TreeMC1.Crec
    And
    TreeMC.Node >> TreeMC1.Node
    And
    CurOwner == TreeMc.cRec
  )) 
;

TabbedSheet right b1;
Tree tGrMc 'Дерево';
 Fields
  TreeMC.Name 'Матценности';
!  TreeMC.Node 'Узел': [1];
  TreeMC.NameGr 'Группа';
End;

Screen screenGrMc 'Окно';
 Fields
  TreeMC.Name;
!  TreeMC.Node;
  TreeMC.NameGr;
<<

        Матценности: .@@@@@@@@@@@@@@@@@@

        Группа     : .@@@@@@@@@@@@@@@@@@

>>
End;
End;

 
HandleEvent
  cmInit:
   {
    _LOOP GroupMc
     {
     ClearBuffer(#TreeMC);
     TreeMC.Nrec:=GroupMC.Nrec;
     TreeMC.Name:=GroupMC.Name;
     TreeMC.NameGr:='';
     TreeMC.Crec:=0;
     TreeMc.Node:=1;
     Insert Current TreeMC;
     }

    _LOOP KatMc Where ((KatMC.cGroupMC == GroupMC.Nrec))
     {
     ClearBuffer(#TreeMC);
//     TreeMC.Nrec:=40000000000000h+KatMc.Nrec;// Иначе при равенстве Nrec будет 
                                             // зацикливание. 
     TreeMC.Nrec:=KatMc.Nrec;
     TreeMC.NameGr:=GroupMC.Name;
     TreeMC.Name:=KatMc.Name;
     TreeMC.Crec:=KatMc.cGroupMC;
     TreeMc.Node:=0;
     Insert Current TreeMC;
     }

     
   }
  cmTreeNodeType:
   {
    if (Not IsValidAll(tnTreeMC1)) then 
      TreeSetNodeType(tGrMc,ntfText,'bmpTextCatal')
!      TreeSetNodeType(tGrMc,ntfText)

      else
          {
           if(TreeNodeIsOpen(tGrMc)) then
             TreeSetNodeType(tGrMc,ntfOpen,'bmpOpenCatal');
!             TreeSetNodeType(tGrMc,ntfOpen);
            else 
             TreeSetNodeType(tGrMc,ntfClose,'bmpCloseCatal');   
!             TreeSetNodeType(tGrMc,ntfClose);   
 	  }   
   }
  cmTreeTop:
   {
    CurOwner:=0;
   }
  cmTreeDown:
   {
    CurOwner:=TreeMC.Nrec;
   }                
  cmTreeUp:
   {
    CurOwner:=TreeMC.Crec;
   }
End;
End.